Te damos la bienvenida a nuestra web, ahora hallarás la resolución de lo que estás buscando.
Solución:
Sin uso SendKeys
Option Explicit
Private Declare Sub keybd_event Lib "user32" (ByVal bVk As Byte, ByVal _
bScan As Byte, ByVal dwFlags As Long, ByVal dwExtraInfo As Long)
Private Const VK_SNAPSHOT = &H2C
Sub PrintScreen()
keybd_event VK_SNAPSHOT, 1, 0, 0
ActiveSheet.Paste
End Sub
Sin embargo, con este enfoque, si está utilizando varios monitores, solo capturará la activo monitor, por lo que se deben realizar más esfuerzos si necesita capturar el otro monitor (esto probablemente se pueda hacer con llamadas a la API, pero no he llegado tan lejos).
NB: El AppActivate La declaración se puede utilizar para activar otra aplicación (que no sea de Excel) y, si lo hace, keybd_event la función será solamente capturar esa aplicación, por ejemplo;
AppActivate "Windows Command Processor" 'Modify as needed
keybd_event VK_SNAPSHOT, 1, 0, 0
ActiveSheet.Paste
Utilizando SendKeys, Problema resuelto:
Tiempo SendKeys es notoriamente inestable, si necesita utilizar este método debido a las limitaciones del método API descrito anteriormente, es posible que tenga algunos problemas. Como ambos observamos, la llamada a ActiveSheet.Paste en realidad no estaba pegando la pantalla de impresión, sino que estaba pegando lo que estaba previamente en la cola del Portapapeles, en el sentido de que necesitaba hacer clic en su botón para llamar al macro dos veces, antes de que realmente pegue la captura de pantalla.
Intenté algunas cosas diferentes en vano, pero pasé por alto lo obvio: mientras depuraba, si pongo un punto de interrupción en ActiveSheet.Paste, ¡Ya no veía el problema descrito anteriormente!
Esto me dice que el SendKeys no se procesa lo suficientemente rápido como para poner los datos en el Portapapeles antes de que se ejecute la siguiente línea de código, para resolver ese problema hay dos posibles soluciones.
- Tu podrías intentar
Application.Wait. Este método parece funcionar cuando lo pruebo, pero advierto que tampoco es confiable. - Una mejor opcion seria
DoEvents, porque está diseñado explícitamente para manejar este tipo de cosas:
DoEvents pasa el control al sistema operativo. El control se devuelve después de que el sistema operativo haya terminado de procesar los eventos en su cola y todos keys en el SendKeys la cola ha sido enviada.
Esto funciona para mí si ejecuto el macro manualmente desde el IDE, desde la cinta Macros o desde un botón Click procedimiento de evento:
Option Explicit
Sub CopyScreen()
Application.SendKeys "(1068)", True
DoEvents
ActiveSheet.Paste
Dim shp As Shape
With ActiveSheet
Set shp = .Shapes(.Shapes.Count)
End With
End Sub
Cómo colocar, cambiar el tamaño y recortar la imagen:
Independientemente del método que utilice, una vez que la imagen se haya pegado utilizando ActiveSheet.Paste será una Forma que podrás manipular.
Para cambiar el tamaño: una vez que tenga un identificador en la forma, simplemente asigne su Height y Width propiedades según sea necesario:
Dim shp As Shape
With ActiveSheet
Set shp = .Shapes(.Shapes.Count)
End With
shp.Height = 600
shp.Width = 800
Para colocarlo: usa la forma TopLeftCell propiedad.
Para recortarlo: utilizar el shp.PictureFormat.Crop (y / o CropLeft, CropTop, CropBottom, CropRight si necesita ajustar qué parte de la captura de pantalla se necesita. Por ejemplo, esto recorta la captura de pantalla pegada a 800×600:
Dim h As Single, w As Single
h = -(600 - shp.Height)
w = -(800 - shp.Width)
shp.LockAspectRatio = False
shp.PictureFormat.CropRight = w
shp.PictureFormat.CropBottom = h
Puede probar este código en un módulo estándar en Excel de 32 bits.
- Las capturas de pantalla se pueden capturar inmediatamente llamando Sub prcSave_Picture_Screen y capturará toda su pantalla y la guardará en la misma ruta que su libro de trabajo (puede cambiar la ruta y el nombre del archivo si lo desea)
- También se pueden capturar capturas de pantalla de una ventana activa después de llamar Sub prcSave_Picture_Active_Window 3 segundos (que es ajustable)
Fuente: ms-office-forum.de
Option Explicit
Private Declare Sub Sleep Lib "kernel32.dll" ( _
ByVal dwMilliseconds As Long)
Private Declare Function OleCreatePictureIndirect Lib "olepro32.dll" ( _
ByRef PicDesc As PicBmp, _
ByRef RefIID As GUID, _
ByVal fPictureOwnsHandle As Long, _
ByRef IPic As IPicture) As Long
Private Declare Function CreateCompatibleDC Lib "gdi32.dll" ( _
ByVal hdc As Long) As Long
Private Declare Function CreateCompatibleBitmap Lib "gdi32.dll" ( _
ByVal hdc As Long, _
ByVal nWidth As Long, _
ByVal nHeight As Long) As Long
Private Declare Function SelectObject Lib "gdi32.dll" ( _
ByVal hdc As Long, _
ByVal hObject As Long) As Long
Private Declare Function GetDeviceCaps Lib "gdi32.dll" ( _
ByVal hdc As Long, _
ByVal iCapabilitiy As Long) As Long
Private Declare Function GetSystemPaletteEntries Lib "gdi32.dll" ( _
ByVal hdc As Long, _
ByVal wStartIndex As Long, _
ByVal wNumEntries As Long, _
ByRef lpPaletteEntries As PALETTEENTRY) As Long
Private Declare Function CreatePalette Lib "gdi32.dll" ( _
ByRef lpLogPalette As LOGPALETTE) As Long
Private Declare Function SelectPalette Lib "gdi32.dll" ( _
ByVal hdc As Long, _
ByVal hPalette As Long, _
ByVal bForceBackground As Long) As Long
Private Declare Function RealizePalette Lib "gdi32.dll" ( _
ByVal hdc As Long) As Long
Private Declare Function BitBlt Lib "gdi32.dll" ( _
ByVal hDestDC As Long, _
ByVal x As Long, _
ByVal y As Long, _
ByVal nWidth As Long, _
ByVal nHeight As Long, _
ByVal hSrcDC As Long, _
ByVal xSrc As Long, _
ByVal ySrc As Long, _
ByVal dwRop As Long) As Long
Private Declare Function DeleteDC Lib "gdi32.dll" ( _
ByVal hdc As Long) As Long
Private Declare Function GetDC Lib "user32.dll" ( _
ByVal hWnd As Long) As Long
Private Declare Function GetWindowRect Lib "user32.dll" ( _
ByVal hWnd As Long, _
ByRef lpRect As RECT) As Long
Private Declare Function GetSystemMetrics Lib "user32.dll" ( _
ByVal nIndex As Long) As Long
Private Declare Function GetForegroundWindow Lib "user32.dll" () As Long
Private Const SM_CXSCREEN = 0&
Private Const SM_CYSCREEN = 1&
Private Const RC_PALETTE As Long = &H100
Private Const SIZEPALETTE As Long = 104
Private Const RASTERCAPS As Long = 38
Private Type RECT
Left As Long
Top As Long
Right As Long
Bottom As Long
End Type
Private Type PALETTEENTRY
peRed As Byte
peGreen As Byte
peBlue As Byte
peFlags As Byte
End Type
Private Type LOGPALETTE
palVersion As Integer
palNumEntries As Integer
palPalEntry(255) As PALETTEENTRY
End Type
Private Type GUID
Data1 As Long
Data2 As Integer
Data3 As Integer
Data4(7) As Byte
End Type
Private Type PicBmp
Size As Long
Type As Long
hBmp As Long
hPal As Long
Reserved As Long
End Type
Public Sub prcSave_Picture_Screen() 'ganzer bildschirm
stdole.SavePicture hDCToPicture(GetDC(0&), 0&, 0&, _
GetSystemMetrics(SM_CXSCREEN), GetSystemMetrics(SM_CYSCREEN)), _
ThisWorkbook.Path & "Screenshot.bmp" 'anpassen !!!
End Sub
Public Sub prcSave_Picture_Active_Window() 'aktives Fenster
Dim hWnd As Long
Dim udtRect As RECT
Sleep 3000 '3 sekunden pause um ein anderes Fenster zu aktivieren
hWnd = GetForegroundWindow
GetWindowRect hWnd, udtRect
stdole.SavePicture hDCToPicture(GetDC(0&), udtRect.Left, udtRect.Top, _
udtRect.Right - udtRect.Left, udtRect.Bottom - udtRect.Top), _
ThisWorkbook.Path & "Screenshot.bmp" 'anpassen !!!
End Sub
Private Function CreateBitmapPicture(ByVal hBmp As Long, ByVal hPal As Long) As Object
Dim Pic As PicBmp, IPic As IPicture, IID_IDispatch As GUID
With IID_IDispatch
.Data1 = &H20400
.Data4(0) = &HC0
.Data4(7) = &H46
End With
With Pic
.Size = Len(Pic)
.Type = 1
.hBmp = hBmp
.hPal = hPal
End With
Call OleCreatePictureIndirect(Pic, IID_IDispatch, 1, IPic)
Set CreateBitmapPicture = IPic
End Function
Private Function hDCToPicture(ByVal hDCSrc As Long, ByVal LeftSrc As Long, _
ByVal TopSrc As Long, ByVal WidthSrc As Long, ByVal HeightSrc As Long) As Object
Dim hDCMemory As Long, hBmp As Long, hBmpPrev As Long
Dim hPal As Long, hPalPrev As Long, RasterCapsScrn As Long, HasPaletteScrn As Long
Dim PaletteSizeScrn As Long, LogPal As LOGPALETTE
hDCMemory = CreateCompatibleDC(hDCSrc)
hBmp = CreateCompatibleBitmap(hDCSrc, WidthSrc, HeightSrc)
hBmpPrev = SelectObject(hDCMemory, hBmp)
RasterCapsScrn = GetDeviceCaps(hDCSrc, RASTERCAPS)
HasPaletteScrn = RasterCapsScrn And RC_PALETTE
PaletteSizeScrn = GetDeviceCaps(hDCSrc, SIZEPALETTE)
If HasPaletteScrn And (PaletteSizeScrn = 256) Then
LogPal.palVersion = &H300
LogPal.palNumEntries = 256
Call GetSystemPaletteEntries(hDCSrc, 0, 256, LogPal.palPalEntry(0))
hPal = CreatePalette(LogPal)
hPalPrev = SelectPalette(hDCMemory, hPal, 0)
Call RealizePalette(hDCMemory)
End If
Call BitBlt(hDCMemory, 0, 0, WidthSrc, HeightSrc, hDCSrc, LeftSrc, TopSrc, 13369376)
hBmp = SelectObject(hDCMemory, hBmpPrev)
If HasPaletteScrn And (PaletteSizeScrn = 256) Then
hPal = SelectPalette(hDCMemory, hPalPrev, 0)
End If
Call DeleteDC(hDCMemory)
Set hDCToPicture = CreateBitmapPicture(hBmp, hPal)
End Function
Aquí tienes las comentarios y calificaciones
Si conservas algún titubeo y disposición de progresar nuestro escrito te invitamos dejar una crítica y con deseo lo interpretaremos.