Pegar el rango de Excel en Outlook

Solución:

Antes que nada, RangeToHTML. El guión lo llama como un método, pero no lo es. Es un popular función por MVP Ron de Bruin. Casualmente, esos enlaces apuntan a la fuente exacta del script que publicaste, antes de que esas pocas líneas se modificaran.

Sigamos con Range.SpecialCells. Este método opera en un rango y devuelve solo aquellas celdas que coinciden con los criterios dados. En su caso, parece que sólo le interesan los texto visible células. Es importante destacar que opera en un Distancia, no en texto HTML.

En aras de la integridad, publicaré una versión funcional del script a continuación. Sin duda, aconsejaría ignorarlo y volver a visitar el excelente original de Ron the Bruin.

Sub Mail_Selection_Range_Outlook_Body()

Dim rng As Range
Dim OutApp As Object
Dim OutMail As Object

Set rng = Nothing
' Only send the visible cells in the selection.

Set rng = Sheets("Sheet1").Range("D4:D12").SpecialCells(xlCellTypeVisible)

If rng Is Nothing Then
    MsgBox "The selection is not a range or the sheet is protected. " & _
           vbNewLine & "Please correct and try again.", vbOKOnly
    Exit Sub
End If

With Application
    .EnableEvents = False
    .ScreenUpdating = False
End With

Set OutApp = CreateObject("Outlook.Application")
Set OutMail = OutApp.CreateItem(0)


With OutMail
    .To = ThisWorkbook.Sheets("Sheet2").Range("C1").Value
    .CC = ""
    .BCC = ""
    .Subject = "This is the Subject line"
    .HTMLBody = RangetoHTML(rng)
    ' In place of the following statement, you can use ".Display" to
    ' display the e-mail message.
    .Display
End With
On Error GoTo 0

With Application
    .EnableEvents = True
    .ScreenUpdating = True
End With

Set OutMail = Nothing
Set OutApp = Nothing
End Sub


Function RangetoHTML(rng As Range)
' By Ron de Bruin.
    Dim fso As Object
    Dim ts As Object
    Dim TempFile As String
    Dim TempWB As Workbook

    TempFile = Environ$("temp") & "https://foroayuda.es/" & Format(Now, "dd-mm-yy h-mm-ss") & ".htm"

    'Copy the range and create a new workbook to past the data in
    rng.Copy
    Set TempWB = Workbooks.Add(1)
    With TempWB.Sheets(1)
        .Cells(1).PasteSpecial Paste:=8
        .Cells(1).PasteSpecial xlPasteValues, , False, False
        .Cells(1).PasteSpecial xlPasteFormats, , False, False
        .Cells(1).Select
        Application.CutCopyMode = False
        On Error Resume Next
        .DrawingObjects.Visible = True
        .DrawingObjects.Delete
        On Error GoTo 0
    End With

    'Publish the sheet to a htm file
    With TempWB.PublishObjects.Add( _
         SourceType:=xlSourceRange, _
         Filename:=TempFile, _
         Sheet:=TempWB.Sheets(1).Name, _
         Source:=TempWB.Sheets(1).UsedRange.Address, _
         HtmlType:=xlHtmlStatic)
        .Publish (True)
    End With

    'Read all data from the htm file into RangetoHTML
    Set fso = CreateObject("Scripting.FileSystemObject")
    Set ts = fso.GetFile(TempFile).OpenAsTextStream(1, -2)
    RangetoHTML = ts.ReadAll
    ts.Close
    RangetoHTML = Replace(RangetoHTML, "align=center x:publishsource=", _
                          "align=left x:publishsource=")

    'Close TempWB
    TempWB.Close savechanges:=False

    'Delete the htm file we used in this function
    Kill TempFile

    Set ts = Nothing
    Set fso = Nothing
    Set TempWB = Nothing
End Function

A menudo, esta pregunta se hace en el contexto de Ron de Bruin. RangeToHTML función, que crea un HTML PublishObject desde un Excel.Range, lo extrae a través de FSO e inserta el HTML de flujo resultante en el correo electrónico HTMLBody. Al hacerlo, esto elimina la firma predeterminada (la RangeToHTML la función tiene una función auxiliar GetBoiler que intenta insertar la firma predeterminada).

Desafortunadamente, el pobremente documentado Application.CommandBars El método no está disponible a través de Outlook:

wdDoc.Application.CommandBars.ExecuteMso "PasteExcelTableSourceFormatting"

Generará un tiempo de ejecución 6158:

Pero aún podemos aprovechar el Word.Document que es accesible a través del MailItem.GetInspector método, podemos hacer algo como esto para copiar y pegar la selección de Excel en el cuerpo del correo electrónico de Outlook, conservando su firma predeterminada (si hay una).

Dim rng as Range
Set rng = Range("A1:F10") 'Modify as needed

With OutMail
    .To = "[email protected]"
    .BCC = ""
    .Subject = "Subject"
    .Display
    Dim wdDoc As Object     '## Word.Document
    Dim wdRange As Object   '## Word.Range
    Set wdDoc = OutMail.GetInspector.WordEditor
    Set wdRange = wdDoc.Range(0, 0)
    wdRange.InsertAfter vbCrLf & vbCrLf
    'Copy the range in-place
    rng.Copy
    wdRange.Paste
End With

Tenga en cuenta que en algunos casos esto puede no preservar perfectamente los anchos de las columnas o, en algunos casos, las alturas de las filas, y aunque también copiará formas y otros objetos en el rango de Excel, esto también puede causar algunos problemas de alineación extravagantes, pero para tablas simples y Rangos de Excel, es muy bueno:

---

---

Utiliza Nuestro Buscador