Apple – Crear un nuevo archivo (.txt) en Finder – Atajo de teclado

Puede darse el caso de que halles algún error en tu código o proyecto, recuerda probar siempre en un entorno de testing antes añadir el código al trabajo final.

Solución:

Bueno, aquí tienes un AppleScript para eso.

Primero, crea el AppleScript:

1. Automatizador abierto
2. Crear un Acción rapida
3. Establezca la entrada en sin entrada
4. Arrastre y suelte el Ejecutar AppleScript elemento de flujo de trabajo en el espacio gris.
5. Pegue el código de abajo en el AppleScript
6. Guardar el flujo de trabajo como Crear nuevo archivo

   Si tiene iCloud Drive activado, asegúrese de guardar el archivo en Library/Services/ en su carpeta de inicio.

---

try
  tell application "Finder" to set the this_folder ¬
   to (folder of the front window) as alias
on error -- no open folder windows
  set the this_folder to path to desktop folder as alias
end try

set thefilename to text returned of (display dialog ¬
 "Create file named:" default answer "filename.txt")
set thefullpath to POSIX path of this_folder & thefilename
do shell script "touch "" & thefullpath & """

---

Para agregarlo como acceso directo:

• Vaya a Preferencias del sistema -> Teclado -> Accesos directos -> Servicios
• Desplácese hacia abajo hasta encontrar el Servicio Crear nuevo archivo
• Asígnele un acceso directo haciendo clic en el lado derecho ningunaque se convierte en un Añadir atajo.
  Haga clic en el botón y escriba el atajo que desea usar.
  yo suelo ⌘ Comando+⌥ Opción+norte

He creado un AppleScript muy similar al de @YoshiBotX, pero con algunas mejoras.

La idea es crear un flujo de trabajo de Automator y asignarle un acceso directo siguiendo los siguientes pasos:

• Abierto Automatizador y crear un Servicio;
• Establezca la entrada en sin entraday la aplicación a Finder.aplicación;
• Arrastre y suelte el Ejecutar AppleScript elemento de flujo de trabajo en el espacio gris;
• Coloque el contenido de este AppleScript en el cuadro de texto;
• Guarde el flujo de trabajo con un nombre razonable (como Archivo nuevo);
• Ir Configuración -> Teclado -> Accesos directos -> Servicios y asígnele un acceso directo.

Ahora, mostremos el AppleScript:

set file_name to "untitled"
set file_ext to ".txt"
set is_desktop to false

-- get folder path and if we are in desktop (no folder opened)
try
    tell application "Finder"
        set this_folder to (folder of the front Finder window) as alias
    end tell
on error
    -- no open folder windows
    set this_folder to path to desktop folder as alias
    set is_desktop to true
end try

-- get the new file name (do not override an already existing file)
tell application "System Events"
    set file_list to get the name of every disk item of this_folder
end tell
set new_file to file_name & file_ext
set x to 1
repeat
    if new_file is in file_list then
        set new_file to file_name & " " & x & file_ext
        set x to x + 1
    else
        exit repeat
    end if
end repeat

-- create and select the new file
tell application "Finder"

    activate
    set the_file to make new file at folder this_folder with properties name:new_file
    if is_desktop is false then
        reveal the_file
    else
        select window of desktop
        set selection to the_file
        delay 0.1
    end if
end tell

-- press enter (rename)
tell application "System Events"
    tell process "Finder"
        keystroke return
    end tell
end tell

Para mayor comodidad, estoy poniendo este AppleScript en este GitHub Gist.

También podría asignar un acceso directo a un script como este:

tell application "Finder"
    set selection to make new file at (get insertion location)
end tell

La ubicación de inserción es el destino de la ventana del Finder que se encuentra más adelante o el escritorio.

Puedes añadir valor a nuestra información aportando tu veteranía en las observaciones.

---

---

Utiliza Nuestro Buscador