Use Oracle PL/SQL For Loop para iterar a través de delimitado por comas string

Hola usuario de nuestra web, hallamos la respuesta a tu interrogante, has scroll y la encontrarás un poco más abajo.

Solución:

Podrías hacerlo fácilmente en puro sql. hay varias formas de hacerlo, mira División delimitada por comas string en filas en Oracle

Sin embargo, si realmente quieres hacerlo en PL/SQLentonces podrías hacerlo como:

SQL> set serveroutput on
SQL> DECLARE
  2    str VARCHAR2(100) := 'PEBO,PTGC,PTTL,PTOP,PTA';
  3  BEGIN
  4    FOR i IN
  5    (SELECT trim(regexp_substr(str, '[^,]+', 1, LEVEL)) l
  6    FROM dual
  7      CONNECT BY LEVEL <= regexp_count(str, ',')+1
  8    )
  9    LOOP
 10      dbms_output.put_line(i.l);
 11    END LOOP;
 12  END;
 13  /
PEBO
PTGC
PTTL
PTOP
PTA

PL/SQL procedure successfully completed.

SQL>

Gracias a las excelentes instrucciones de Lalit, puedo crear una función a la que puedo llamar desde mi for círculo:

Crear un tipo y función

CREATE OR REPLACE TYPE t_my_list AS TABLE OF VARCHAR2(100);
CREATE OR REPLACE
       FUNCTION comma_to_table(p_list IN VARCHAR2)
         RETURN t_my_list
       AS
         l_string VARCHAR2(32767) := p_list || ',';
         l_comma_index PLS_INTEGER;
         l_index PLS_INTEGER := 1;
         l_tab t_my_list     := t_my_list();
       BEGIN
         LOOP
           l_comma_index := INSTR(l_string, ',', l_index);
           EXIT
         WHEN l_comma_index = 0;
           l_tab.EXTEND;
           l_tab(l_tab.COUNT) := TRIM(SUBSTR(l_string,l_index,l_comma_index - l_index));
           l_index            := l_comma_index + 1;
         END LOOP;
         RETURN l_tab;
       END comma_to_table;
/

Entonces cómo llamarlo en mi por círculo:

declare
  v_list_pak_like varchar2(4000) := 'PEBO,PTGC,PTTL,PTOP,PTA';
begin
    FOR x IN (select * from (table(comma_to_table(v_list_pak_like)) ) )
    loop
        dbms_output.put_line(x.COLUMN_VALUE);
    end loop;
end;
/

Observe el nombre predeterminado COLUMN_VALUE dado por Oracle que es necesario para el uso que quiero hacer del resultado.

Resultado como se esperaba:

PEBO
PTGC
PTTL
PTOP
PTA

Aquí puedes ver las reseñas y valoraciones de los usuarios

---

---

Utiliza Nuestro Buscador