¿Cómo habilitar las funciones de vista previa de Java 12 con Gradle?

Solución:

Necesita configurar el JavaCompile tareas, para que Gradle pase esta opción al compilador de Java al compilar.

Algo como esto debería funcionar:

tasks.withType(JavaCompile).each {
    it.options.compilerArgs.add('--enable-preview')
}

Para ejecutar la aplicación / pruebas necesitamos agregar jvmArgs.

Ejemplo:

test {
    jvmArgs(['--enable-preview'])
}

Actualmente no parece haber un solo lugar para definir eso. Debe hacerlo para todos los tipos de tareas (compilación, ejecución de prueba o tareas relacionadas con Java exec). Me encontré completamente cubierto con:

tasks.withType(JavaCompile) {
    options.compilerArgs += "--enable-preview"
}

tasks.withType(Test) {
    jvmArgs += "--enable-preview"
}

tasks.withType(JavaExec) {
    jvmArgs += '--enable-preview'
}

Aquí hay otra versión que usa Gradle Kotlin DSL para su uso en build.gradle.kts:

plugins {
    `java-library`
}

repositories {
    mavenCentral()
}

java {
    sourceCompatibility = JavaVersion.VERSION_12
}

tasks.withType<JavaCompile> {
    options.compilerArgs.add("--enable-preview")
}
tasks.test {
    useJUnitPlatform()
    jvmArgs("--enable-preview")
}

dependencies {
    testImplementation("org.junit.jupiter:junit-jupiter-api:5.4.2")
    testImplementation("org.junit.jupiter:junit-jupiter-engine:5.4.2")
}

---

---

Utiliza Nuestro Buscador